【Amazon】
バッファロー 6TB 外付けHDD HD-NRLD6.0U3-BA

バッファロー

弾はそれ一つ一つ独立したノード（オブジェクト）となります。そのため、シーンで弾自体を用意します。予めファイルシステムには、画像などを入れる assets、シーンを入れる scenes、スクリプトを入れる scripts フォルダを作っておきます。

Godot では、ゲーム内のあらゆる要素はノードで構成され、それらをまとめたものがシーンになります。ノードは「部品」、シーンは「組み立て済」だと考えてください。

scenes に bullet.tscn を Node2D で作成します。空っぽの Bullet がシーンとして作成されます。出来たシーンを右クリックして型を変更を選択します。検索で Spr と入れて表示される Sprite2D を選択して変更ボタンを押します。

これでシーンのノードはスプライトになりました。弾の画像を assets にコピーしてから、インスペクターの Texture にその画像を設定してください。

続いてスクリプトです。Bullet シーンのインスペクター一番下にある Script <空> を左クリックして新規スクリプト...を選択します。そのまま作ると scenes フォルダにスクリプトファイルが作られます。折角スクリプトフォルダを作りましたから、パスをそちらに変更してください。最後に作成ボタンを押します。空っぽのスクリプトファイルが作成されます。

extends Sprite2D
class_name Bullet

var dir:Vector2 = Vector2.ZERO		#移動方向と速度

signal bullet_finished(node, value)	#移動終了時のお知らせシグナル

const SCREEN_SIZE:Vector2i = Vector2i(640, 400)
const SCR_RANGE:Rect2 = Rect2(-8, -8, SCREEN_SIZE.x + 16, SCREEN_SIZE.y + 16)

#初期化
func _init() -> void:
	_reset()

#弾の状態をリセットする
func _reset() -> void:
	hide()
	dir = Vector2.ZERO
	process_mode = Node.PROCESS_MODE_DISABLED

#弾を発射する
func start(rad:float, speed:float, pos:Vector2) -> void:
	global_position = pos
	dir = Vector2.RIGHT.rotated(rad) * speed
	show()
	process_mode = Node.PROCESS_MODE_INHERIT

#経過処理
func _process(_delta: float) -> void:
	if dir == Vector2.ZERO: return
	global_position += dir * _delta
	if SCR_RANGE.has_point(global_position): return
	emit_signal("bullet_finished", self, -1)
	_reset()

【Amazon】
ゲームを動かす数学・物理 R

堂前嘉樹

ボーンデジタル

2021-04-20

#定数
const BULLET = preload("res://scenes/Bullet.tscn")	#弾シーンの読み込み
const MAX_BULLETS = 1000				#同時存在最大数
const FIRE_SPEED:float = 250				#弾速
const FIRE_WAIT:float = 0.04				#弾幕発射の時間間隔
const FIRE_NEXT_ANGLE:float = 48			#次の弾発射の差分角度
const FIRE_SEGMENTS:int = 5				#同時発射弾幕数
const FIRE_POSITION:Vector2 = Vector2(320, 200)		#発射位置

#プロパティ
var empty:Array = []		#空きリスト
var bullets:Array = []		#使用中リスト
var timer:float = 0		#発射間隔タイマー
var fire_angle:float = 0	#発射初期方向
var max_bullet:int = 0

#初期化
func _ready() -> void:
	var win = get_window()
	win.content_scale_size =  Vector2i(640, 400)

	for i in range(MAX_BULLETS):
		var blt = BULLET.instantiate()
		blt.connect("bullet_finished", Callable(self, "_on_bullet_signal"))
		add_child(blt)
		empty.append(blt)

#弾終了シグナル受信
func _on_bullet_signal(_node, _value):
	bullets.erase(_node)		#使用中リストから削除
	empty.append(_node)		#空きリストに追加

#経過処理
func _process(_delta: float) -> void:
	if max_bullet < bullets.size():
		max_bullet = bullets.size()
		print("同時存在最大数:", max_bullet)

	timer += _delta
	if timer < FIRE_WAIT: return

	timer -= FIRE_WAIT

	for i in range(FIRE_SEGMENTS):
		var rad = fire_angle + i * TAU / FIRE_SEGMENTS
		var blt = empty.pop_back() as Bullet
		if not blt: break
		blt.start(rad, FIRE_SPEED, FIRE_POSITION)
		bullets.append(blt)

	fire_angle = fmod(fire_angle + TAU / FIRE_NEXT_ANGLE, TAU)

const FIRE_SPEED:float = 250

const FIRE_WAIT:float = 0.04

const FIRE_NEXT_ANGLE:float = 48

const FIRE_SEGMENTS:int = 5

const FIRE_POSITION:Vector2 = Vector2(320, 200)

const MAX_BULLETS = 1000		#同時存在最大数
const FIRE_SPEED:float = 500		#弾速
const FIRE_WAIT:float = 0.01		#弾幕発射の時間間隔
const FIRE_NEXT_ANGLE:float = 100	#次の弾発射の差分角度
const FIRE_SEGMENTS:int = 5		#同時発射弾幕数

const MAX_BULLETS = 2000		#同時存在最大数
const FIRE_SPEED:float = 250		#弾速
const FIRE_WAIT:float = 0.04		#弾幕発射の時間間隔
const FIRE_NEXT_ANGLE:float = 1		#次の弾発射の差分角度
const FIRE_SEGMENTS:int = 64		#同時発射弾幕数

const MAX_BULLETS = 1000		#同時存在最大数
const FIRE_SPEED:float = 250		#弾速
const FIRE_WAIT:float = 0.25		#弾幕発射の時間間隔
const FIRE_NEXT_ANGLE:float = 1		#次の弾発射の差分角度
const FIRE_SEGMENTS:int = 180		#同時発射弾幕数

どうでしょうか。上記で説明した弾幕処理は以下からダウンロードできます。読み込みと実行は Godot v4.5.1 で行ってください。この記事で使ったプロジェクト一式は以下からダウンロードできます。

【Amazon】
ロジテック 超小型 USBメモリ 128GB Type-A USB 3.2 Gen1 フラッシュメモリー フラッシュドライブ 読込速度200MB/秒 LMC-LS128U3

ロジテックダイレクト